!lasso_tagexists('podcast_categories') ?
define_constant(
	'categories', 
	-namespace='podcast_',
	map(
		'Arts' = (: 'Design', 'Fashion & Beauty', 'Food', 'Literature', 'Performing Arts', 'Visual Arts'),
		'Business' = (: 'Business News', 'Careers', 'Investing', 'Management & Marketing', 'Shopping'),
		'Comedy' = array,
		'Education' = (: 'Education Technology', 'Higher Education', 'K-12', 'Language Courses', 'Training'),
		'Games & Hobbies' = (: 'Automotive', 'Aviation', 'Hobbies', 'Other Games', 'Video Games'),
		'Government & Organizations' = (: 'Local', 'National', 'Non-Profit', 'Regional'),
		'Health' = (: 'Alternative Health', 'Fitness & Nutrition', 'Self-Help', 'Sexuality'),
		'Kids & Family' = array,
		'Music' = array,
		'News & Politics' = array,
		'Religion & Spirituality' = (: 'Buddhism', 'Christianity', 'Hinduism', 'Islam', 'Judaism', 'Other', 'Spirituality'),
		'Science & Medicine' = (: 'Medicine', 'Natural Sciences', 'Social Sciences'),
		'Society & Culture' = (: 'History', 'Personal Journals', 'Philosophy', 'Places & Travel'),
		'Sports & Recreation' = (: 'Amateur', 'College & High School', 'Outdoor', 'Professional'),
		'Technology' = (: 'Gadgets', 'Tech News', 'Podcasting', 'Software How-To'),
		'TV & Film' = array
	)
);



define_type(
	'podcast',
	-description='Extends [xml_tree] specifically for the podcast RSS format.'
);
	local('data' = xml_tree);

	define_tag(
		'onCreate',
		-opt='title',
		-opt='link',
		-opt='language',
		-opt='copyright',
		-opt='description',
		-opt='subtitle',
		-opt='author',
		-opt='summary',
		-opt='block',
		-opt='explicit',
		-opt='keywords',
		-opt='image',
		-opt='ownername',
		-opt='owneremail',
		-opt='new-feed-url',
		-opt='items',
		-opt='category',
		-opt='subcats', -type='array'
	);
		self->'data'->setname('rss');
		self->'data'->addattribute('version'='2.0');
		self->'data'->addnamespace('itunes'='http://www.itunes.com/dtds/podcast-1.0.dtd');
		self->'data'->newchild('channel');
		
		iterate((:'title', 'link', 'language', 'copyright', 'description'), local('i'));
			if(local_defined(#i));
				self->'data'->channel->newchild(#i);
				self->'data'->channel->getnode(#i)->addcontent(local(#i));
			/if;
		/iterate;
		
		iterate((:'subtitle', 'author', 'summary', 'block', 'explicit', 'keywords', 'new-feed-url'), local('i'));
			if(local_defined(#i));
				local('nodename' = 'itunes:' + #i);
				self->'data'->channel->newchild(#nodename);
				self->'data'->channel->getnode(#nodename)->addcontent(local(#i));
			/if;
		/iterate;
		
		if(local_defined('image'));
			self->'data'->channel->newchild('itunes:image');
			self->'data'->channel->getnode('itunes:image')->addattribute('href'=#image);
		/if;
		
		// workaround
		iterate((:'ownername', 'owneremail'), local('i'));
			if(local_defined(#i));
				self->'data'->channel->newchild('itunes:owner');
				loop_abort;
			/if;
		/iterate;
		
		iterate((:'ownername', 'owneremail'), local('i'));
			if(local_defined(#i));
				local('nodename' = 'itunes:' + string_removeleading(#i, -pattern='owner'));					
				self->'data'->channel->getnode('itunes:owner')->newchild(#nodename);
				self->'data'->channel->getnode('itunes:owner')->getnode(#nodename)->addcontent(local(#i));
			/if;		
		/iterate;
		
		if(local_defined('category') && podcast_categories->find(#category) != '');
			self->'data'->channel->newchild('itunes:category');
			self->'data'->channel->getnode('itunes:category')->addattribute('text'=#category);
			
			if(local_defined('subcats'));
				iterate(#subcats, local('i'));
					if(podcast_categories->find(#category)->size && podcast_categories->find(#category) >> #i);
						self->'data'->channel->getnode('itunes:category')->newchild('itunes:category');
						self->'data'->channel->getnode('itunes:category')->lastchild->addattribute('text'=#i);
					/if;
				/iterate;
			/if;
		/if;
		
		if(local_defined('items'));
			iterate(#items, local('i'));
				// may have problems getting this to work with xml_tree...
				self->'data'->channel->addchild(xml(#i));
			/iterate;
		/if;
	/define_tag;
	
	define_tag('_unknownTag');
		return(self->'data'->tag_name);
	/define_tag;
	
	define_tag('onConvert');
		return(string(self->'data'));
	/define_tag;
/define_type;



define_type(
	'item',
	-namespace='podcast_',
	-description='Generates XML for a podcast item RSS node.'
);
	local('data' = xml_tree);
	
	define_tag(
		'onCreate',
		-opt='title',
		-opt='author',
		-opt='subtitle',
		-opt='summary',
		-opt='enclosure', -type='map',
		-opt='guid',
		-opt='pubDate', -type='date',
		-opt='duration', -type='duration',
		-opt='keywords',
		-opt='block',
		-opt='explicit'
	);
		self->'data'->setname('item');
		self->'data'->addnamespace('itunes'='http://www.itunes.com/dtds/podcast-1.0.dtd');
		
		iterate((:'title', 'guid'), local('i'));
			if(local_defined(#i));
				self->'data'->newchild(#i);
				self->'data'->getnode(#i)->addcontent(local(#i));
			/if;
		/iterate;
		
		iterate((:'subtitle', 'author', 'summary', 'block', 'explicit', 'keywords', 'duration'), local('i'));
			if(local_defined(#i));
				local('nodename' = 'itunes:' + #i);
				self->'data'->newchild(#nodename);
				self->'data'->getnode(#nodename)->addcontent(local(#i));
			/if;
		/iterate;
		
		if(local_defined('pubDate'));
			self->'data'->newchild('pubDate');
			// Wed, 15 Jun 2005 19:00:00 GMT
			self->'data'->pubDate->addcontent(date_localtogmt(#pubDate)->format('%a, %d %b %Y %H:%M:%S GMT'));
		/if;
		
		if(local_defined('enclosure'));
			self->'data'->newchild('enclosure');
			self->'data'->enclosure->addattribute('url'=#enclosure->find('url'));
			self->'data'->enclosure->addattribute('length'=#enclosure->find('length'));
			self->'data'->enclosure->addattribute('type'=#enclosure->find('type'));
		/if;
		
		// convert to xml type when finished to work around inheritance bugs
		self->'data' = xml(self->'data');
	/define_tag;

	define_tag('_unknownTag');
		return(self->'data'->tag_name);
	/define_tag;
	
	define_tag('onConvert');
		return(string(self->'data'));
	/define_tag;
/define_type;