define_tag('mv_findThread', -required='Name', -copy, -optional='current', -copy, -optional='signal', -copy);
/* current:
  M = Mark the array entry as being the calling thread.  X = eXclude the calling thread from the checks and the result list / signal.  any = Include calling thread in checks and result list without markings.
 signal:		
  Y = simply return true or false instead of a list with found threads.*/
 local(
  'tList' = array,
  'curID' = thread_getcurrentid,
  'insert'= false
 );

	// Set default value to M(ark)
 if(! local_defined('current'));
  local('current') = 'M';
 /if;

	// Set default value to N(o)
 if(! local_defined('signal'));
  local('signal') = 'N';
 /if;

 iterate(Thread_List, local('tmp'));
  #tmp = Thread_Info(#tmp);
  if (#tmp->find('name') >> #name);
   #insert=false;

   if(#tmp->find('id') >> #curID);
    if(#current == 'M');
     #tmp->insert('isMe'='Y');
     #insert=true;
    else(#current != 'X');
     #insert=true;
    /if;
   else;
    #insert=true;
   /if;

   if(#insert);
    if(#signal == 'Y');
     loop_abort;
    /if;
    #tList->insert(#tmp);
   /if;
  /if;
 /iterate;

 if(#signal == 'Y');
  return(#insert);
 else;
  return(#tList);
 /if;

/define_tag;