[

define_tag:'lp_string_wordwrap',
	-description='Word-wraps a string at a given line length.',
	-priority='replace',
	-required='string', -copy,
	-required='linelength',
	-optional='linefeed';
	
	#string = string: #string;
	
	if: !(local_defined:'linefeed');
		local:'linefeed' = (lp_string_linefeedGet: #string);
		if: #linefeed == '';
			#linefeed = '\r\n';
		/if;
	else;
		#linefeed = string: #linefeed;
	/if;

	if: params->(find:'-striplf')->size > 0;
		// strip out the linefeeds
		#string = (lp_string_linefeedSet: #string, ' ');
	/if;

	
	if: #linefeed == 'array';
		local:'return' = array;
		local:'temp' = string;
		local:'notrunaway' = 1000;
		while: #string->size && #notrunaway;
			#notrunaway -= 1;
			#temp = (lp_string_firstwords: #string, (integer:#linelength));
			#string->(removeleading: #temp);
			#temp->trim;
			if: #temp->size;
				#return->(insert: #temp);
			/if;
		/while;
	else;
		local:'return' = string;
		local:'temp' = string;
		local:'notrunaway' = 100000;
		while: #string->size && #notrunaway;
			#notrunaway -= 1;
			#temp = (lp_string_firstwords: #string, (integer:#linelength));
			#string->(removeleading: #temp);
			#temp->trim;
			if: #temp->size;
				#return += #temp #linefeed;
			/if;
		/while;
		#return->trim;
	/if;
	
	return: #return;

/define_tag;

]