[

define_tag:'lp_string_pad',
	-description='Returns a padded string.',
	-priority='replace',
	-required='string',
	-required='length',
	-optional='char';

	// get params 

	local:'str'=string:#string;
	local:'len'=integer:#length;

	local:'pad' = '0';
	if: local_defined:'char';
		#pad = (string:#char);	
	/if;

	local:'padalign'='left';
	if: params->(find:'-padright')->size > 0 || params->(find:'-alignleft')->size > 0;
		#padalign = 'right';
	else: params->(find:'-padcenterright')->size > 0 || params->(find:'-aligncenterleft')->size > 0;
		#padalign = 'centerright';
	else: params->(find:'-padcenterleft')->size > 0 || params->(find:'-aligncenterright')->size > 0;
		#padalign = 'centerleft';
	/if;


	local:'crop'='none';
	if: params->(find:'-cropleft')->size > 0;
		#crop='left';
	else: params->(find:'-cropright')->size > 0;
		#crop='right';
	/if;

	if: params->(find:'-notrim')->size == 0;
		// trim it
		#str->trim;
	/if;

	
// work the magic 

	// if the string len and the wanted len are equal, just return the string
	if: #str->size == #len;
		return:#str;
	else: #str->size > #len;
		if: #crop == 'right';
			return:#str->(substring:1,#len);
		else: #crop == 'left';
			return:#str->(substring:#str->size - #len + 1,#str->size);
		else;
			return:#str;
		/if;
	else; // #str->size < #len
		local:'padlen' = #len - #str->size;
		if: #padalign == 'left';
			#str = (#pad * #padlen) + #str;
		else: #padalign == 'right';
			#str += (#pad * #padlen);
		else: (lp_integer_even: #padlen);
			#str = (#pad * (math_floor: #padlen / 2)) + #str + (#pad * (math_floor: #padlen / 2));
		else: #padalign == 'centerright';
			#str = (#pad * (math_floor: #padlen / 2)) + #str + (#pad * (1 + (math_floor: #padlen / 2)));
		else: #padalign == 'centerleft';
			#str = (#pad * (1 + (math_floor: #padlen / 2))) + #str + (#pad * (math_floor: #padlen / 2));
		/if;
		return:#str;
	/if;
/define_tag;

]