[

// NOTE: [lp_site_restart] will only work when this is loaded via the root LassoStartup

if: site_id == 0;

	// init server - create asyncronous listener
	{
		local:'keycodes' = map;
		local:'inbound' = net;
		#inbound->(bind: 21012);
		while: true;
			protect;
				handle_error;
					log_critical:'[lp_site_restart] ERROR: ' + error_msg;
					#connection->close;
				/handle;
				#inbound->listen;
				local:'connection' = #inbound->accept;		
				local:'command' = (string: (#connection->(read: 2048)));
				#command = #command->(split:' ');
				local:'cmmd' = #command->(get: 1);
				local:'site' = (integer: #command->(get: 2));
				local:'code' = #command->(get: 3);
				if: #cmmd->size && #site && #code->size == 1000;
					if: #cmmd->(equals:'RESTART', -Case);
						if: #keycodes->(find: #site) != null && #keycodes->(find: #site)->(equals: #code, -Case);
							log_critical: '[lp_site_restart] RESTARTING SITE #' + #site;
							#keycodes->(insert: #site = null); // reset key
							server_sitestop: #site;
							server_sitestart: #site;
						/if;
					else: #cmmd->(equals:'REGISTER', -Case);
						if: #keycodes->(find: #site) == null;
							#keycodes->(insert: #site = #code);
						/if;
					/if;
				/if;
				#connection->close;
			/protect;
		/while;
		#inbound->close;
	}->asasync;

	sleep: 1000; // give some time for the listener to kick on

else;

	// init client
	{
	
		// create siteRestartKey
		local:'siteRestartKey' = string;
		local:'alpha' = 'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789!@#$%^&*()_+{}[];:,./<>?|`~';
		local:'upper' = #alpha->size;
		loop: 1000;
			#siteRestartKey += #alpha->(get: (math_random: -lower=1, -upper=#upper));
		/loop;
	
		// register siteRestartKey
		local:'outbound' = net;
		#outbound->(connect: '127.0.0.1', 21012);
		#outbound->(write:'REGISTER ' + site_id + ' ' + #siteRestartKey + ' \r\n');
		#outbound->close;	
	
		// create site-specific ctag using siteRestartKey
		process: "[
		define_tag:'restart', -namespace='_global_lp_site_',
			-description='Restarts the current Lasso site.',
			-priority='replace',
			-async,
			-optional='wait'; // time in milliseconds to wait before shutting down

			if: !(local_defined:'wait');
				local:'wait' = 10;
			/if;
			sleep: (integer: #wait);
			local:'outbound' = net;
			#outbound->(connect: '127.0.0.1', 21012);
			#outbound->(write:'RESTART " + site_id + " " + #siteRestartKey + " \r\n');
			#outbound->close;
		/define_tag;	
		]";
	
		
	}->run;

/if;


]