[

define_tag:'lp_math_median',
	-description='Returns the median average value given an array of values.',
	-priority='replace',
	-required='numbers', -type='array',
	-optional='precision';

	// did we get a precision?
	if:!(local_defined:'precision');
		// nope, set it to zero
		local:'precision' = 0;
	/if;

	// convert array of items into array of lp_decimals
	local:'numbers_array' = array;

	iterate: #numbers, local:'number';
		#numbers_array->(insert: (decimal: #number));
	/iterate;

	// sort in order
	#numbers_array->sort;
	
	local:'midpoint' = integer:(math_ceil: (decimal: (decimal: #numbers_array->size) / (decimal: 2)));

	if: (lp_integer_odd: #numbers_array->size);
		return: (lp_decimal_precisionSet: (decimal: #numbers_array->(get: #midpoint)), (integer:#precision));		
	else; // even
		return: (lp_decimal_precisionSet: (lp_math_mean: (array:(decimal: #numbers_array->(get: #midpoint)),(decimal: #numbers_array->(get: #midpoint + 1)))) , (integer:#precision));
	/if;

/define_tag;

]