[

define_type:'lp_inline_dataset',
	-description='Records abstraction type.',
	-prototype;

	// based on code from Greg Willits, James Harvard and Fletcher Sandbeck (TotW)

	local:'records_array' = array;
	local:'field_names' = array;
	local:'error_msg' = string;
	local:'error_code' = integer;
	local:'found_count' = integer;
	local:'shown_count' = integer;
	local:'shown_first' = integer;
	local:'shown_last' = integer;
	local:'page_count' = integer;
	local:'skiprecords_value' = integer;
	local:'maxrecords_value'  = integer;
	local:'database_name'  = string;
	local:'table_name'  = string;
	local:'keyfield_name'  = string;
	local:'schema_name'  = string;
	local:'lasso_currentaction'  = string;
	local:'action_statement'  = string;

	define_tag:'onCreate';
		self->'records_array' = @records_array;
		self->'field_names' = @field_names;
		self->'error_msg' = @error_msg;
		self->'error_code' = @error_code;
		self->'found_count' = @found_count;
		self->'shown_count' = @shown_count;
		self->'shown_first' = @shown_first;
		self->'shown_last' = @shown_last;
		self->'page_count' = (math_ceil:(found_count / (decimal:maxrecords_value)));
		self->'skiprecords_value' = @skiprecords_value;
		self->'maxrecords_value'  = @maxrecords_value;
		self->'database_name' = @database_name;
		self->'table_name' = @table_name;
		self->'keyfield_name' = @keyfield_name;
		self->'schema_name' = @schema_name;
		self->'lasso_currentaction' = @lasso_currentaction;
		self->'action_statement' = @action_statement;
	/define_tag;

	define_tag:'onConvert';
		return: @self->'records_array';
	/define_tag;
	
	define_tag:'size';
		return: @self->'records_array'->size;
	/define_tag;

	define_tag:'get',-optional='ptr';
		if: !local_defined:'ptr';
			#ptr = 1;
		/if;
		return: @(lp_inline_rowset: @self->'records_array'->(get: #ptr),@self->'field_names');
	/define_tag;
	
/define_type;

define_type:'lp_inline_rowset',
	-description='Row abstraction type.',
	-prototype;
	
	local:'row_array' = array;
	local:'field_names' = array;

	define_tag:'onCreate',-required='row_array',-required='field_names';
		self->'row_array' = @#row_array;
		self->'field_names' = @#field_names;
	/define_tag;
	
	define_tag:'onConvert';
		return: @self->'row_array';
	/define_tag;

	define_tag:'size';
		return: @self->'row_array'->size;
	/define_tag;
	
	define_tag:'get',-optional='ptr';
		if: !local_defined:'ptr';
			#ptr = 1;
		/if;
		return: @self->'row_array'->(get: #ptr);
	/define_tag;

	define_tag:'_unknowntag';
		local:'index' = self->'field_names'->(findindex: tag_name);
		if: #index->size == 0;
			return: null;
		else;
			return: @self->'row_array'->(get: (#index->(get:1)));
		/if;
	/define_tag;
		
/define_type;

]