define_tag:'lp_include_url',
    -description='Charset-aware include_url, returns string instead of bytes.',
    -priority='replace';

    local:'lp_params' = params;
    local:'lp_headers' = '_lp_include_url_headers';
    if: #lp_params->(find:'-RetrieveMIMEHeaders')->size;
        #lp_headers = #lp_params->(find:'-RetrieveMIMEHeaders')->(get:1)->value;
    else;
        #lp_params->(insert:'-RetrieveMIMEHeaders'=#lp_headers);
    /if;
	local:'lp_charset' = string;
	if: params->(find:'-charset')->size && params->(find:'-charset')->(get:1)->type == 'pair';
		local:'lp_charset' = #lp_params->(find:'-charset')->(get:1)->value;
		#lp_params->(removeall:'-charset');
	/if;

    local:'lp_bytes' = @\include_url->(run: -name='include_url', -owner='include_url', -params=#lp_params);

	if: #lp_charset->size == 0;
	    #lp_charset = (string_findregexp: (var: #lp_headers), -find='(?i)charset\\s*=\\s*([\\w\\-]+)');
	    if: #lp_charset->size == 2;
	        #lp_charset = #lp_charset->(get:2);
	    else;  // charset not found in headers, try meta on page
	    	local:'lp_page_top' = (string: #lp_bytes->(getrange: 1, 1024)); // only look in first 1k of page
		    #lp_charset = (string_findregexp: #lp_page_top, -find='(?i)charset\\s*=\\s*([\\w\\-]+)');
		    if: #lp_charset->size == 2;
		        #lp_charset = #lp_charset->(get:2);
			else;
		        #lp_charset = 'utf-8';  // default is utf-8 if all else fails
			/if;
	    /if;
 	/if;

    if: #lp_charset == 'utf-8';
        return: (string: #lp_bytes);
    else;
        return: #lp_bytes->(exportstring:#lp_charset);
    /if;

/define_tag;