define_type: 'flattenparams',
	-namespace='js_',
	-prototype;
	local: 'params'=array,
		'createlocals'=map;
	define_tag: 'oncreate';
		params = params -> first;
		local: 'param', 'element', 'convertparam';
		// loop until we reach the last param element (the params array will possibly grow while looping so we can't just iterate)
		while: loop_count <= (params -> size);
			#param -> detachreference;
			#param = @(params -> (get: loop_count));
			if: #param -> isa('array') || #param -> isa('map') || #param -> isa('treemap');
				// convert non-array parameters to arrays
				if: !(#param -> isa('array'));
					#convertparam=array;
					iterate: #param, #element;
						if: #element -> isa('pair') && #element -> value === null;
							// plain keyword without value
							#convertparam -> insert(#element -> name);
						else;
							#convertparam -> insert(#element);
						/if;
					/iterate;
					// replace existing param non-array structure with converted param array
					#param=#convertparam;
				/if;
				// we want to merge the array with the rest of the params
				// but first we want to remember what locals need to be auto-assigned from the array.
				iterate: #param, #element;
					if: #element -> isa('pair') 
						&& #element -> name -> isa('string') && #element -> name -> beginswith('-') 
						// there is no point in creating references here since they will be copied when the array is merged later
						(self -> 'createlocals') -> insert((#element->name - '-') = (#element->value));
					else: #element -> isa('string')
						&& #element -> beginswith('-') 
						// plain keyword without value
						(self -> 'createlocals') -> insert((#element - '-') = null);
					/if;
				/iterate;
				// merge the array into the params at the right position (this will kill any reference)
				params -> (merge: #param, loop_count);
				
				// replace the array with null so we know we can delete it later
				#param=null;
			/if;
		/while;
		// remove all ex arrays that we have merged into the params array
		params -> (removeall: null);
		// return the params we saw
		(self -> 'params') = params;
	/define_tag;
	
	define_tag: 'params';
		return: @(self -> 'params');
	/define_tag;

	define_tag: 'locals';
		return: @(self -> 'createlocals');
	/define_tag;
/define_type;